set bWdSet = ("8 16 24 32" "16 24 32" "24 32" "32")
foreach aWd ("8" "16" "24" "32")
  foreach bWd ($bWdSet[1])
    set outCnt = 1
    foreach lib ("vhdl" "vlog")
      source make-$lib

      set elabopt = ("" "-neverwarn -notimingchecks -noipd -no_tchk_msg -no_tchk_xgen -no_vpd_msg -no_vpd_xgen")
      set simopt  = ("" "-neverwarn -nocifcheck")
      foreach vhdlopt ("" "-neverwarn -nopragmawarn -novitalcheck")

	rm -r work
	mkdir work
	echo ncvhdl -nocopyright -v93 -nostdout -nolog $vhdlopt '<vhdFile>' \
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo "------------------------------------------------"		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo -n running ncvhdl $vhdlopt
	foreach vhd  ("mul${aWd}x${bWd}S.vhd" "mulTstS.vhd" "mul${aWd}Cfg.vhd")
	  echo -n $vhd": "			>> ncsim.${aWd}x${bWd}.time.$lib
          (time ncvhdl -nocopyright -v93 -nostdout -nolog $vhdlopt $vhd) \
						>>&ncsim.${aWd}x${bWd}.time.$lib
	end

	echo ncelab -nocopyright -v93 -nostdout -nolog \\		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo "      $elabopt[1] -generic 'aWdC=>$aWd'" \\		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo "      -generic 'bWdC=>$bWd' -generic 'cyclesC=>50000'" \\ \
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo "      mul${aWd}Cfg"		>> ncsim.${aWd}x${bWd}.time.$lib
	echo "------------------------------------------------"		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo -n " - ncelab ${aWd}x${bWd}"
	(time ncelab -nocopyright -v93 -nostdout -nolog $elabopt[1]	\
	  -generic "aWdC=>$aWd" -generic "bWdC=>$bWd"			\
	  -generic "cyclesC=>50000" mul${aWd}Cfg)			\
						>>&ncsim.${aWd}x${bWd}.time.$lib

	echo ncsim -nocopyright -batch -input ncsim.scr \\		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo "     "-nostdout -nokey -logfile tmpout    \\		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo "     "$simopt[1] mul${aWd}Cfg	>> ncsim.${aWd}x${bWd}.time.$lib
	echo "------------------------------------------------"		\
						>> ncsim.${aWd}x${bWd}.time.$lib
	echo -n " - ncsim"
	foreach run (1 2)
	  echo -n " "$run
	  (time ncsim -nocopyright -batch -input ncsim.scr -nostdout -nokey \
		-logfile tmpout $simopt[1] mul${aWd}Cfg)		\
						>>&ncsim.${aWd}x${bWd}.time.$lib
	  mv tmpout tmpout.${aWd}x${bWd}.${outCnt}
	  @ outCnt++
	end
	echo ""					>> ncsim.${aWd}x${bWd}.time.$lib
	echo ""
	shift elabopt
	shift simopt
      end
    end
  end
  shift bWdSet
end
unset bWdSet
unset elabopt
unset simopt
unset outCnt
