rm -r WORK/*
echo vhdlan -nc -cycle -event tlcWalk.vhd tlcWalk1.vhd tlcTst.vhd >> cyc.time
echo "------------------------------------------------"		>> cyc.time
(time vhdlan -nc -cycle -event tlcWalk.vhd tlcWalk1.vhd tlcTst.vhd) >>& cyc.time
echo ""								>> cyc.time

set outCnt = 1
foreach arch ("walkCfg" "walk1Cfg")
  foreach sta ("-4state" "-2state")
    set simopt = ("-debug" "-debug"      "-perf" "-perf")
    foreach opt  ("-debug" "-debug -tbl" "-perf" "-perf -tbl")
      echo cylab -nc -t ns $sta $opt $arch			>> cyc.time
      echo "------------------------------------------------"	>> cyc.time
      (time cylab -nc -t ns $sta $opt -o /dev/null $arch)	>>& cyc.time 
      foreach rew ("-rewind" "")
	echo -n $arch -running $sta $opt / $rew ...
	echo cysim -nc -t ns $sta $simopt[1] $rew -i cyc.scr $arch >> cyc.time
	echo "------------------------------------------------" >> cyc.time
	foreach run (1 2 3)
	  echo -n " "$run
	  (time cysim -nc -t ns $sta $simopt[1] $rew -i cyc.scr \
		-o tmpout $arch)				>>& cyc.time
	  mv tmpout tmpout.$outCnt
	  @ outCnt++
	end
	echo ""
      end
      echo ""							>> cyc.time
      shift simopt
    end
  end
end
unset simopt
unset outCnt
