set bWdSet = ("8 16 24 32" "16 24 32" "24 32" "32")
foreach aWd ("8" "16" "24" "32")
  foreach bWd ($bWdSet[1])
    set outCnt = 1

    rm -r WORK/*
    echo vhdlan -nc -cycle -event mulPkg mul8 mul16 mul24 mul32 mulTst	\
						>> sci01.${aWd}x${bWd}.time
    echo "------------------------------------------------"		\
						>> sci01.${aWd}x${bWd}.time
    (time vhdlan -nc -cycle -event mulPkg.vhd mul8.vhd mul16.vhd	\
	mul24.vhd mul32.vhd mulTst.vhd)		>>&sci01.${aWd}x${bWd}.time
    echo ""					>> sci01.${aWd}x${bWd}.time
    echo "assign ${aWd} aWdC"			>  sci.gen
    echo "assign ${bWd} bWdC"			>> sci.gen
    echo "assign 50000 cyclesC"			>> sci.gen
    echo "assign (20 ns) periodC"		>> sci.gen
    echo "cycle -2state -perf -tbl mul${aWd}"	>  mul.part
    echo "cycle -2state -perf -tbl mul${aWd}Cfg">  tst.part

    set scsopt = ("-noperf" "" "-partition mul.part"			\
	"-2state -partition tst.part") 
    foreach simopt  ("-debug_all" "" "" "")
      echo -n running ${aWd}x${bWd} $scsopt[1] scs
      echo scs -nc -time ns $scsopt[1] -generics sci.gen mul${aWd}Cfg	\
						>> sci01.${aWd}x${bWd}.time
      echo "------------------------------------------------"		\
						>> sci01.${aWd}x${bWd}.time
      (time scs -nc -time ns $scsopt[1] -generics sci.gen mul${aWd}Cfg)	\
						>>&sci01.${aWd}x${bWd}.time

      echo -n "- scsim ..."
      echo scsim -nc $simopt -include sci.scr -output tmpout		\
						>> sci01.${aWd}x${bWd}.time
      echo "------------------------------------------------"		\
						>> sci01.${aWd}x${bWd}.time
      foreach run (1 2 3)
	echo -n " "$run
        (time scsim -nc $simopt -include sci.scr -output tmpout)	\
						>>&sci01.${aWd}x${bWd}.time
	mv tmpout tmpout01.${aWd}x${bWd}.$outCnt
	@ outCnt++
      end
      echo ""
      echo ""					>> sci01.${aWd}x${bWd}.time
      shift scsopt
    end
  end
  shift bWdSet
end
unset scsopt
unset bWdSet
unset outCnt
