set bWdSet = ("8 16 24 32" "16 24 32" "24 32" "32")
foreach aWd ("8" "16" "24" "32")
  foreach bWd ($bWdSet[1])
    set outCnt = 1
    foreach lib ("" "-opt")
      rm -r work/*
      echo 'INCLUDE $CDS_INST_DIR/tools/leapfrog/files/cds.lib'	      >  cds.lib
      echo 'INCLUDE /local/tech1.1/cds/ldv3.1/share/cdssetup/cds.lib' >> cds.lib
      echo 'DEFINE work work'					      >> cds.lib
      echo 'DEFINE csx_hrdlib /local/tech1.1/ams/vhdlLib/sv/csx33/csx_HRDLIB'$lib >> cds.lib

      set evopt = ("-performance"					\
	"-performance -noipd -notcheck -vitalmsgoff -vitalxoff")
      foreach cvopt ("-avopt -performance"				\
  "-avopt -performance -bounds -underover -notcheck -vitalmsgoff -vitalxoff")

	echo cv -nocopyright -v93 $cvopt '<vhdFile>'			\
						>> sv.${aWd}x${bWd}.time$lib
	echo "------------------------------------------------"		\
						>> sv.${aWd}x${bWd}.time$lib
	echo -n running cv
	foreach vhd  ("mul${aWd}x${bWd}X.vhd" "mulTstS.vhd" "mul${aWd}Cfg.vhd")
	  echo -n $vhd": "			>> sv.${aWd}x${bWd}.time$lib
	  (time cv -nocopyright -v93 $cvopt $vhd)			\
						>>&sv.${aWd}x${bWd}.time$lib
	end

	echo ev -nocopyright -v93 $evopt[1] \\	>> sv.${aWd}x${bWd}.time$lib
	echo "   -generic 'aWdC=>$aWd' -generic 'bWdC=>$bWd'" \\	\
						>> sv.${aWd}x${bWd}.time$lib
	echo "   -generic 'cyclesC=>50000' mul${aWd}Cfg" \
						>> sv.${aWd}x${bWd}.time$lib
	echo "------------------------------------------------"		\
						>> sv.${aWd}x${bWd}.time$lib
	echo -n " - ev ${aWd}x${bWd}"
	(time ev -nocopyright -v93 $evopt[1] -generic "aWdC=>$aWd"	\
	  -generic "bWdC=>$bWd" -generic "cyclesC=>50000" mul${aWd}Cfg)\
						>>&sv.${aWd}x${bWd}.time$lib

	echo sv -nocopyright -batch -input sv.scr -output tmpout mul${aWd}Cfg \
						>> sv.${aWd}x${bWd}.time$lib
	echo "------------------------------------------------"		\
						>> sv.${aWd}x${bWd}.time$lib
	echo -n " - sv"
	foreach run (1 2)
	  echo -n " "$run
	  (time sv -nocopyright -batch -input sv.scr -output tmpout	\
		mul${aWd}Cfg)			>>& sv.${aWd}x${bWd}.time$lib
	  mv tmpout tmpout.${aWd}x${bWd}.${outCnt}
	  @ outCnt++
	end
	echo ""					>> sv.${aWd}x${bWd}.time$lib
	echo ""
	shift evopt
      end
    end
  end
  shift bWdSet
end
unset bWdSet
unset evopt
unset outCnt
